kdb+ Trade Quote Chart

Adding a kdb+ Server
Populating Data
Adding our Trade Blotter
Customizing Table Appearance

Download Pulse

Add kdb+ Server Connection

To add a connection goto Connections->"Add Data Connection" and fill in your details.
You can try clicking test to see if the connection works before adding it.

Populating the Tables

Copy and Paste the below code into the SQL Editor and press "Send Query":

/ random walk functions
r:{{ abs ((1664525*x)+1013904223) mod 4294967296}\[y-1;x]};
walk:{ [r;seed;n] prds (100+((r[seed;n]) mod 11)-5)%100}[r;;];

/ Generate 3 tables for the select sym/time. roffset is used to generate different random walks.
gen:{[sym;tim;roffset]
  c:{x mod `long$00:05:00.0t}tim; st:tim-c; cn:100+`long$c%500;
 t:([] time:.z.d+st+1000*til cn; bid:walk[100+roffset;cn]);
 rnd:{[r;roffset;seed;n] (r[seed+roffset;n] mod 1000)%1000}[r;roffset;];
 t:update ask:bid+0.1*rnd[10;cn] from t;
 filter:{select from x  where (not null buy) or (not null sell)};
 addSym:{update sym:x from y}[sym;];
 clientt:filter select time-00:00:00.001,buy:?[rnd[11;cn]>0.92;bid-rnd[11;cn]*0.03;0n],sell:?[rnd[15;cn]>0.92;ask+rnd[11;cn]*0.03;0n] from t;
 clientt:update bsize:?[null buy; 0n; 1+r[14;count i] mod 10],ssize:?[null sell; 0n; 1+r[14;count i] mod 10] from clientt;
 hedgert:filter select time+00:00:00.001,buy:?[rnd[11;cn]>0.98;bid-rnd[11;cn]*0.01;0n],sell:?[rnd[15;cn]>0.98;ask+rnd[11;cn]*0.01;0n] from t;
 hedgert:update bsize:?[null buy; 0n; 6+r[14;count i] mod 14],ssize:?[null sell;0n;6+r[14;count i] mod 14] from hedgert;
 `quotes`clientt`hedgert!(addSym t;addSym clientt;addSym hedgert)};
// sym:`GOOG; tim:10:04t; roffset:0;
setTables:{key[x] set' value x};
setTables gen[`GOOG; 10:04t; 0];
append:{key[x] insert' value x};
append gen[`AAPL; 10:04t; 2];
append gen[`META; 10:04t; 3];

This will create three tables:

quotes - Containing time,bid,ask,sym columns.
clientt - Where each row is a Client Trade at a specified time and buy/sell price and size.
hedgert - Where each row is a Hedger Trade at a specified time and buy/sell price and size.
The hedger makes infrequent trades to reduce risk positions.

Add and Edit Dashboard

On the dashboards listing page, click add
Click on the newly created dashboard to go into it. Either click on edit or toggle design mode once in the dashboard.

Add Real-Time Quote Graph

Click Time-Series to add that component
Make sure your kdb+ data source is selected
Select the refresh rate. Every 250ms
Enter the SQL query `time xdesc select from quotes where sym=`AAPL, click save or press ctrl+E.
Note the xdesc is required as the position of the labels is decided by the order of the data.

Joining Trades To Quotes

Replace the table query with the below:

`time xdesc (`time xkey select from quotes where sym=`AAPL)
         uj (`time xkey select time,
                                        buy_SD_CIRCLE:buy, buy_SD_SIZE:bsize,
                                       sell_SD_CIRCLE:sell,   sell_SD_SIZE:ssize
                                                   from clientt where sym=`AAPL)

Once you save you should see a chart similar to that shown below. Notice:

The special naming buy_SD_CIRCLE means render those items as circular points only.
The related column buy_SD_SIZE controls the size of the circles.

This behaviour including additional shapes etc. is documented further in our TAQ chart docs.

Joining Hedger Trades To Quotes

We can similarly union join the hedgert table to get hedger trades as triangles like so:

`time xdesc (`time xkey select from quotes where sym=`AAPL)
         uj (`time xkey select time,
                                        buy_SD_CIRCLE:buy, buy_SD_SIZE:bsize,
                                       sell_SD_CIRCLE:sell,   sell_SD_SIZE:ssize
                                                   from clientt where sym=`AAPL)
         uj (`time xkey select time,
                                        hedger_buy_SD_TRIANGLE:buy, hedger_buy_SD_SIZE:bsize,
                                       hedger_sell_SD_TRIANGLE:sell,   hedger_sell_SD_SIZE:ssize
                                                   from hedgert where sym=`AAPL)

Next - Try it yourself

Thanks for watching our demo. Please download Pulse to give it a try for yourself.